1 REM: ***ENGLISH DARTS***
2 :
5 REM: ***INITIALIZATION***
7 :
10 C$=CHR$(147):D$=CHR$(17):H$=CHR$(19):F$=CHR$(144):RF$=CHR$(146):RO$=CHR$(18)
20 C1$=CHR$(28):C2$=CHR$(30):C3$=CHR$(31):C4$=CHR$(156):C5$=CHR$(158):BC=53280
30 C6$=CHR$(159):V=53248:CL=646:S=102:NA$="*ENGLISH DARTS*":A$="":SN$="":B$=""
40 RD=1:POKE53281,1:POKEBC,9:FORK=0TO62:READA:POKE832+K,A:NEXT
50 FORK=0TO62:READA:POKE896+K,A:NEXT:FORK=49152TO49245:READA:POKEK,A:NEXT
60 POKE49152+19,0:POKE2041,13:POKE2042,14:POKE2043,14:POKE2044,14:SYS49152
62 :
65 REM: ***BILLBOARD***
67 :
70 GOSUB750:GOSUB620:PRINT:PRINT:PRINTF$TAB(12)NA$:GOSUB740
80 PRINTC2$RO$TAB(13)" WHICH GAME? ":PRINT:PRINTTAB(8)"301 "RO$" <1> ";
90 PRINTRF$" OR 501 "RO$" <2> ":PRINT
100 GETK$:K=VAL(K$):IFK<1ORK>2THEN100
110 IFK=1THENGA=301:GOTO130
120 GA=501
130 PRINTRO$TAB(7)" NUMBER OF PLAYERS? "RF$" (1-7)"
140 GETK$:Z=VAL(K$):IFZ<1ORZ>7THEN140
150 GOSUB650
152 :
155 REM: ***SCREEN PRINT***
157 :
160 POKEBC,1:PRINTH$RO$"            "NA$"        ":REM*  -11- AND -8- SPACES
170 PRINTC5$RO$" PLAYER NUMBER "RF$PP;
180 PRINTC3$RO$TAB(20)" DART NUMBER   "RF$TH
190 PRINTC4$RO$" ROUND SCORE   "RF$RS;
200 PRINTC1$RO$TAB(20)" ROUND NUMBER  "RF$RD
210 PRINTC2$RO$" CURRENT SCORE "RF$TP(PP);
220 PRINTC6$RO$TAB(20)" # OF PLAYERS  "RF$Z:GOSUB740:FORK=1TOZ:CC=K+1:POKECL,CC
230 PRINTRO$TAB(21)" PLAYER # "RF$K;:PRINTTP(K):NEXT:GOSUB740
240 PRINTC4$TAB(1)A$:PRINT:PRINTF$TAB(7)SN$:PRINT:PRINTC4$TAB(4)B$:PRINT
245 IFTH>3THENGOSUB720:FORK=1TO9:POKEV+K,0:NEXT:GOSUB650:GOTO160
250 POKE198,0:GOSUB720:PRINTC5$"PRESS "RO$F$"<KEY>"RF$C5$" TO TOSS"
252 :
255 REM: ***THROW SEQUENCE***
257 :
260 FORK=1664TO1683:POKEK,32:NEXT:FORK=1744TO1763:POKEK,32:NEXT
270 FORK=1824TO1843:POKEK,32:NEXT:IFTH=1THENQ=4:W=5:Y=215:G=6:GOTO300
280 IFTH=2THENQ=6:W=7:Y=211:G=14:GOTO300
290 IFTH=3THENQ=8:W=9:Y=219:G=30
300 POKEV+21,G:POKEV+23,2:POKEV+29,28:FORK=1TOZ:IFK=PPTHENCC=K+1:GOTO320
310 NEXT
320 POKEV+40,11:FORK=41TO43:POKEV+K,CC:NEXT:POKEV+2,255:POKEV+3,90
330 FORL=90TO110:POKEV+Q,30:POKEV+W,L:IFPEEK(198)=1THEN370
340 FORT=1TO10:NEXTT:NEXTL
350 FORL=110TO90STEP-1:POKEV+Q,30:POKEV+W,L:IFPEEK(198)=1THEN370
360 FORT=1TO10:NEXTT:NEXTL:GOTO330
370 FORK=1904TO1923:POKEK,32:NEXT:POKEV+Q,0:POKEV+W,0:POKE198,0:POKEV+21,G
380 FORK=30TOY:POKEV+Q,K:POKEV+W,L:NEXT:GOSUB730:R=N:GOSUB730:D=N
390 A=0:FORK=80TO99:A=A+1:IFL=KTHEN430
400 NEXT
410 A=21:FORK=101TO110:A=A-2:IFL=KTHEN430
420 NEXT:IFL=100THENA=50
430 IFA=50THENB=A:A$="YOU THREW A...":SN$="BULLSEYE!":GOTO480
440 IFA=RANDA=DTHENB=A*3:A$="YOU THREW A TRIPLE":GOTO470
450 IFA=RTHENB=A*2:A$="YOU THREW A DOUBLE":GOTO470
460 B=A:A$="YOU THREW A SINGLE"
470 SN$=STR$(A)
480 B$="FOR"+STR$(B)+" POINTS":TP(PP)=TP(PP)+B:RS=RS+B
485 IFTP(PP)=GATHENFORK=1TO9:POKEV+K,0:NEXT:GOTO560
490 IFTP(PP)>GATHENFORK=1TO9:POKEV+K,0:NEXT:GOTO520
500 TH=TH+1:GOTO160
512 :
515 REM: ***BROKE STATEMENT***
517 :
520 POKEBC,2:GOSUB750:GOSUB620:GOSUB740
530 PRINTC4$TAB(14)"YOU THREW"B:PRINT:PRINTTAB(18)"AND":PRINT
540 PRINTF$TAB(14)"B*R*O*K*E!!":PRINTC4$:GOSUB720:TP(PP)=TP(PP)-B
550 RS=0:TH=1:GOSUB650:FORK=1TO9:POKEV+K,0:NEXT:GOTO160
552 :
555 REM: ***WINNER STATEMENT***
557 :
560 POKEBC,5:GOSUB750:GOSUB620:GOSUB740:PRINTC4$TAB(5)NA$" WINNER IS..."
570 PRINT:GOSUB720:PRINTF$TAB(10)"PLAYER NUMBER"PP:PRINT
572 PRINT:PRINTC4$TAB(8)"SEE FINAL SCORES? (Y/N)"
574 GETK$:IFK$=""THEN574
576 IFK$="Y"THENPP=Z:NU=1:GOTO650
577 IFK$="N"THEN580
578 IFK$<>"Y"ORK$<>"N"THEN574
579 GOSUB740
580 PRINT:PRINTC5$RO$TAB(10)" PLAY AGAIN? "RF$" (Y/N)"
590 GETK$:IFK$=""THEN590
595 IFK$="Y"THENCLR:GOTO10
600 PRINTC$:GOSUB740:PRINTC2$TAB(12)NA$:PRINT:PRINTTAB(17)"E*N*D":GOSUB720
610 POKEV+21,0:PRINTC$:END
612 :
615 REM: ***SPRITE LOGO***
617 :
620 POKEV+21,30:POKEV+23,2:POKEV+29,28:POKEV+40,12:POKEV+41,11:POKEV+42,12
630 POKEV+43,15:POKEV+2,180:POKEV+3,100:POKEV+4,144:POKEV+5,104:POKEV+6,147
640 POKEV+7,111:POKEV+8,142:POKEV+9,118:RETURN
642 :
645 REM: ***NEXT PLAYER/BOX SCORE SUBROUTINE***
647 :
650 POKEBC,5:GOSUB750:GOSUB620:TH=1:RS=0:PP=PP+1:IFPP>ZTHEN680
660 GOSUB740:PRINTC2$TAB(8)"PLAYER NUMBER"F$PP;:PRINTC2$"UP NEXT":GOSUB720
670 FORK=1TO9:POKEV+K,0:NEXT:A$="":SN$="":B$="":PRINTC$:RETURN
680 PRINT:PRINT:PRINTC2$RO$TAB(4)" PLAYER NUMBER "TAB(25)" POINTS ":PRINT:PRINT
690 FORK=1TOZ:CC=K+1:POKECL,CC:PRINTTAB(10)K;:PRINTTAB(26)TP(K):PRINT:NEXT
700 PRINTH$:FORK=1TO22:PRINTD$;:NEXT:PRINTC4$RO$TAB(12)" PRESS ANY KEY "
710 POKE198,0:WAIT198,1:POKE198,0:RD=RD+1:PP=0:IFNU=1THENGOSUB750:GOTO579
711 GOTO650
712 :
715 REM: ***TIME DELAY SUBROUTINE***
717 :
720 FORT=1TO1500:NEXT:RETURN
722 :
725 REM: ***RANDOM SUBROUTINE***
727 :
730 N=INT(20*RND(0))+1:RETURN
732 :
735 REM: ***CENTER SUBROUTINE***
737 :
740 PRINTH$:FORK=1TO15:PRINTD$;:NEXT:RETURN
742 :
745 REM: ***BORDER SUBROUTINE***
747 :
750 PRINTC$:POKECL,7:FORK=1024TO1063:POKEK,S:NEXT:FORK=1024TO1984STEP40:POKEK,S
760 NEXT:FORK=1063TO2023STEP40:POKEK,S:NEXT:FORK=1984TO2023:POKEK,S:NEXT:RETURN
762 :
765 REM: ***DATA***
767 :
770 DATA0,16,0,0,56,0,0,85
771 DATA0,0,146,0,1,17,0,2
772 DATA56,128,5,85,64,8,146,32
773 DATA17,85,16,34,56,136,127,255
774 DATA252,34,56,136,17,85,16,8
775 DATA146,32,5,85,64,2,56,128
776 DATA1,17,0,0,146,0,0,84
777 DATA0,0,56,0,0,16,0,0
778 DATA0,0,0,0,0,0,0,0
779 DATA0,0,0,0,0,0,0,0
780 DATA0,0,0,0,240,0,0,127
781 DATA0,0,63,254,0,31,255,255
782 DATA63,254,0,127,0,0,254,0
783 DATA0,0,0,0,0,0,0,0
784 DATA0,0,0,0,0,0,0,0
785 DATA0,0,0,0,0,0,173,21
786 DATA192,141,22,192,120,169,24,141
787 DATA20,3,169,192,141,21,3,88
788 DATA96,5,0,20,0,0,206,22
789 DATA192,208,61,173,21,192,141,22
790 DATA192,173,33,208,41,15,141,20
791 DATA192,160,0,132,251,169,216,133
792 DATA252,238,23,192,173,23,192,41
793 DATA1,170,177,251,41,15,205,19
794 DATA192,240,5,205,20,192,208,5
795 DATA189,19,192,145,251,200,208,234
796 DATA230,252,165,252,201,220,208,226
797 DATA76,49,234,52